今天有个需求要在 Windows 下实现数据库自动备份，拼凑了一下解决办法。
实现的特性
可指定多个数据库
按照 年/月/日 的方式组织备份
可选的使用 WinRAR 压缩备份
使用计划任务实现定时备份
具体代码
备份
代码如下:
@echo off & setlocal ENABLEEXTENSIONS
:: ---------- 配置项 ----------
:: 备份放置的路径，加 \
set BACKUP_PATH=D:\Backup\
:: 要备份的数据库名称，多个用空格分隔
set DATABASES=database1 database2 database3
:: MySQL 用户名
set USERNAME=root
:: MySQL 密码
set PASSWORD=123456
:: MySQL Bin 目录，加 \
:: 如果可以直接使用 mysqldump（安装时添加 MySQL Bin 目录到了环境变量），此处留空即可
set MYSQL=D:\SERVER\MySQL\bin\
:: WinRAR 自带命令行工具的可执行文件路径，长文件名注意用 Dos 长文件名书写方式
set WINRAR=C:\Progra~1\WinRAR\Rar.exe
:: ---------- 以下请勿修改 ----------
set YEAR=%date:~0,4%
set MONTH=%date:~5,2%
set DAY=%date:~8,2%
:: 如果在 dos 下输入 time 返回的不是 24 小时制（没有 0 填充），请自行修改此处
set HOUR=%time:~0,2%
set MINUTE=%time:~3,2%
set SECOND=%time:~6,2%
set DIR=%BACKUP_PATH%%YEAR%\%MONTH%\%DAY%\
set ADDON=%YEAR%%MONTH%%DAY%%HOUR%%MINUTE%%SECOND%
:: create dir
if not exist %DIR% (
mkdir %DIR% 2>nul
)
if not exist %DIR% (
echo Backup path: %DIR% not exists, create dir failed.
goto exit
)
cd /d %DIR%
:: backup
echo Start dump databases...
for %%D in (%DATABASES%) do (
echo Dumping database %%D ...
%MYSQL%mysqldump -u%USERNAME% -p%PASSWORD% %%D > %%D.%ADDON%.sql 2>nul
:: winrar
if exist %WINRAR% (
%WINRAR% a -k -r -s -m1 -ep1 %%D.%ADDON%.rar %%D.%ADDON%.sql 2>nul
del /F /S /Q %%D.%ADDON%.sql 2>nul
)
)
echo Done
:exit
增加计划任务
代码如下:
@echo off
:: ------- 配置项 -------
:: 要执行的文件名
set FILE=D:\cron\cron_backup.bat
:: 计划频率类型
set FREQUENCY=DAILY
:: 频率，与上面的计划频率类型对应
set MODIFIER=1
:: 该计划执行的时间（24 小时制）
set DATETIME=00:30:00
:: 计划的名字
set NAME="Backup Cron Job"
:: 计划执行用户，不建议修改
set USER="System"
:: ------- 以下请勿修改 -------
schtasks /Create /RU %USER% /SC %FREQUENCY% /MO %MODIFIER% /ST %DATETIME% /TN %NAME% /TR %FILE%
pause
其中的
:: 计划频率类型，可选项：
:: MINUTE 分钟
:: DAILY 天
:: HOURLY 小时
:: WEEKLY 周
:: MONTHLY 月
:: 频率，与上面的计划频率类型对应
:: MINUTE: 1 到 1439 分钟
:: HOURLY: 1 - 23 小时
:: DAILY: 1 到 365 天
:: WEEKLY: 1 到 52 周
:: MONTHLY: 1 到 12，或 FIRST, SECOND, THIRD, FOURTH, LAST, LASTDAY
使用方法
将上面的两段代码分别保存为 cron_backup.bat 和 cron_backup_add.bat，并根据注释修改相关参数
确定好目录之后，运行 cron_backup_add.bat 将计划任务添加到系统中。
Windows Server 2003 / XP 可以通过 开始，控制面板，计划任务进入计划任务管理界面；
Windows Vista / 7 可以通过 计算机，右键，管理，系统工具，任务计划程序，任务计划程序库，进入计划任务管理界面。
手动运行该任务，查看备份目录来确认下备份是否成功。
待改进
增加删除多少天之前备份的功能
您可能感兴趣的文章:mysql mysqldump只导出表结构或只导出数据的实现方法mysqldump备份还原和mysqldump导入导出语句大全详解MySQL mysqldump命令使用详解用mysqldump备份和恢复指定表的方法使用MySQL MySqldump命令导出数据时的注意事项MySQL数据库使用mysqldump导出数据详解Mysql导入导出工具Mysqldump和Source命令用法详解mysql mysqldump数据备份和增量备份使用mysqldump导入数据和mysqldump增量备份(mysqldump使用方法)mysql数据库备份及恢复命令 mysqldump,source的用法mysqldump命令导入导出数据库方法与实例汇总mysqldump数据库备份参数详解mysql备份恢复mysqldump.exe几个常用用例PHP使用mysqldump命令导出数据库linux下改良版本mysqldump来备份MYSQL数据库mysqldump加-w参数备份数据时需要注意的事项MySQL的mysqldump工具用法详解PHP定时备份MySQL与mysqldump语法参数详解
mysqldump
windows
批处理
Mysql